| ... | @@ -1,127 +0,0 @@ |
| 1 | const std = @import("../std.zig"); |
| 2 | const builtin = @import("builtin"); |
| 3 | const io = std.io; |
| 4 | |
| 5 | /// Provides `io.GenericReader`, `io.GenericWriter`, and `io.SeekableStream` for in-memory buffers as |
| 6 | /// well as files. |
| 7 | /// For memory sources, if the supplied byte buffer is const, then `io.GenericWriter` is not available. |
| 8 | /// The error set of the stream functions is the error set of the corresponding file functions. |
| 9 | pub const StreamSource = union(enum) { |
| 10 | // TODO: expose UEFI files to std.os in a way that allows this to be true |
| 11 | const has_file = (builtin.os.tag != .freestanding and builtin.os.tag != .uefi); |
| 12 | |
| 13 | /// The stream access is redirected to this buffer. |
| 14 | buffer: io.FixedBufferStream([]u8), |
| 15 | |
| 16 | /// The stream access is redirected to this buffer. |
| 17 | /// Writing to the source will always yield `error.AccessDenied`. |
| 18 | const_buffer: io.FixedBufferStream([]const u8), |
| 19 | |
| 20 | /// The stream access is redirected to this file. |
| 21 | /// On freestanding, this must never be initialized! |
| 22 | file: if (has_file) std.fs.File else void, |
| 23 | |
| 24 | pub const ReadError = io.FixedBufferStream([]u8).ReadError || (if (has_file) std.fs.File.ReadError else error{}); |
| 25 | pub const WriteError = error{AccessDenied} || io.FixedBufferStream([]u8).WriteError || (if (has_file) std.fs.File.WriteError else error{}); |
| 26 | pub const SeekError = io.FixedBufferStream([]u8).SeekError || (if (has_file) std.fs.File.SeekError else error{}); |
| 27 | pub const GetSeekPosError = io.FixedBufferStream([]u8).GetSeekPosError || (if (has_file) std.fs.File.GetSeekPosError else error{}); |
| 28 | |
| 29 | pub const Reader = io.GenericReader(*StreamSource, ReadError, read); |
| 30 | pub const Writer = io.GenericWriter(*StreamSource, WriteError, write); |
| 31 | pub const SeekableStream = io.SeekableStream( |
| 32 | *StreamSource, |
| 33 | SeekError, |
| 34 | GetSeekPosError, |
| 35 | seekTo, |
| 36 | seekBy, |
| 37 | getPos, |
| 38 | getEndPos, |
| 39 | ); |
| 40 | |
| 41 | pub fn read(self: *StreamSource, dest: []u8) ReadError!usize { |
| 42 | switch (self.*) { |
| 43 | .buffer => |*x| return x.read(dest), |
| 44 | .const_buffer => |*x| return x.read(dest), |
| 45 | .file => |x| if (!has_file) unreachable else return x.read(dest), |
| 46 | } |
| 47 | } |
| 48 | |
| 49 | pub fn write(self: *StreamSource, bytes: []const u8) WriteError!usize { |
| 50 | switch (self.*) { |
| 51 | .buffer => |*x| return x.write(bytes), |
| 52 | .const_buffer => return error.AccessDenied, |
| 53 | .file => |x| if (!has_file) unreachable else return x.write(bytes), |
| 54 | } |
| 55 | } |
| 56 | |
| 57 | pub fn seekTo(self: *StreamSource, pos: u64) SeekError!void { |
| 58 | switch (self.*) { |
| 59 | .buffer => |*x| return x.seekTo(pos), |
| 60 | .const_buffer => |*x| return x.seekTo(pos), |
| 61 | .file => |x| if (!has_file) unreachable else return x.seekTo(pos), |
| 62 | } |
| 63 | } |
| 64 | |
| 65 | pub fn seekBy(self: *StreamSource, amt: i64) SeekError!void { |
| 66 | switch (self.*) { |
| 67 | .buffer => |*x| return x.seekBy(amt), |
| 68 | .const_buffer => |*x| return x.seekBy(amt), |
| 69 | .file => |x| if (!has_file) unreachable else return x.seekBy(amt), |
| 70 | } |
| 71 | } |
| 72 | |
| 73 | pub fn getEndPos(self: *StreamSource) GetSeekPosError!u64 { |
| 74 | switch (self.*) { |
| 75 | .buffer => |*x| return x.getEndPos(), |
| 76 | .const_buffer => |*x| return x.getEndPos(), |
| 77 | .file => |x| if (!has_file) unreachable else return x.getEndPos(), |
| 78 | } |
| 79 | } |
| 80 | |
| 81 | pub fn getPos(self: *StreamSource) GetSeekPosError!u64 { |
| 82 | switch (self.*) { |
| 83 | .buffer => |*x| return x.getPos(), |
| 84 | .const_buffer => |*x| return x.getPos(), |
| 85 | .file => |x| if (!has_file) unreachable else return x.getPos(), |
| 86 | } |
| 87 | } |
| 88 | |
| 89 | pub fn reader(self: *StreamSource) Reader { |
| 90 | return .{ .context = self }; |
| 91 | } |
| 92 | |
| 93 | pub fn writer(self: *StreamSource) Writer { |
| 94 | return .{ .context = self }; |
| 95 | } |
| 96 | |
| 97 | pub fn seekableStream(self: *StreamSource) SeekableStream { |
| 98 | return .{ .context = self }; |
| 99 | } |
| 100 | }; |
| 101 | |
| 102 | test "refs" { |
| 103 | std.testing.refAllDecls(StreamSource); |
| 104 | } |
| 105 | |
| 106 | test "mutable buffer" { |
| 107 | var buffer: [64]u8 = undefined; |
| 108 | var source = StreamSource{ .buffer = std.io.fixedBufferStream(&buffer) }; |
| 109 | |
| 110 | var writer = source.writer(); |
| 111 | |
| 112 | try writer.writeAll("Hello, World!"); |
| 113 | |
| 114 | try std.testing.expectEqualStrings("Hello, World!", source.buffer.getWritten()); |
| 115 | } |
| 116 | |
| 117 | test "const buffer" { |
| 118 | const buffer: [64]u8 = "Hello, World!".* ++ ([1]u8{0xAA} ** 51); |
| 119 | var source = StreamSource{ .const_buffer = std.io.fixedBufferStream(&buffer) }; |
| 120 | |
| 121 | var reader = source.reader(); |
| 122 | |
| 123 | var dst_buffer: [13]u8 = undefined; |
| 124 | try reader.readNoEof(&dst_buffer); |
| 125 | |
| 126 | try std.testing.expectEqualStrings("Hello, World!", &dst_buffer); |
| 127 | } |
Andrew Kelley <andrew@ziglang.org> 2025-07-20 17:04:00-07:00