| 1 | //! parity - if number of bits set is even => 0, else => 1 |
| 2 | //! - pariytXi2_generic for big and little endian |
| 3 | const compiler_rt = @import("../compiler_rt.zig"); |
| 4 | const symbol = compiler_rt.symbol; |
| 5 | |
| 6 | comptime { |
| 7 | symbol(&__paritysi2, "__paritysi2"); |
| 8 | symbol(&__paritydi2, "__paritydi2"); |
| 9 | symbol(&__parityti2, "__parityti2"); |
| 10 | } |
| 11 | |
| 12 | pub fn __paritysi2(a: i32) callconv(.c) i32 { |
| 13 | return parityXi2(i32, a); |
| 14 | } |
| 15 | |
| 16 | pub fn __paritydi2(a: i64) callconv(.c) i32 { |
| 17 | return parityXi2(i64, a); |
| 18 | } |
| 19 | |
| 20 | pub fn __parityti2(a: i128) callconv(.c) i32 { |
| 21 | return parityXi2(i128, a); |
| 22 | } |
| 23 | |
| 24 | inline fn parityXi2(comptime T: type, a: T) i32 { |
| 25 | var x: @Int(.unsigned, @typeInfo(T).int.bits) = @bitCast(a); |
| 26 | // Bit Twiddling Hacks: Compute parity in parallel |
| 27 | comptime var shift: u8 = @bitSizeOf(T) / 2; |
| 28 | inline while (shift > 2) { |
| 29 | x ^= x >> shift; |
| 30 | shift = shift >> 1; |
| 31 | } |
| 32 | x &= 0xf; |
| 33 | return (@as(u16, 0x6996) >> @intCast(x)) & 1; // optimization for >>2 and >>1 |
| 34 | } |
| 35 | |
| 36 | test { |
| 37 | _ = @import("paritysi2_test.zig"); |
| 38 | _ = @import("paritydi2_test.zig"); |
| 39 | _ = @import("parityti2_test.zig"); |
| 40 | } |